'====================================================================
' AJPapps - Copy file like folder
' Линда Кайе 2010. Посвящается Ариэль
' 
' Этот скрипт копирует файл в текущий каталог и переименовывает его 
' так, чтобы имя соответствовало имени папки. Расширение остаётся 
' прежним. Так, если мы копируем файл C:\Apps\Ariel.EXE в каталог 
' D:\Temp, то конечный файл будет называться D:\Temp\Temp.EXE. 
' Имя исходного файла передаётся через командную строку.
' 
' • 15.12.2010
'   Первая версия ^^
'  
'====================================================================
' Маленький копирайт
' 
' 1. Программа и исходный код распространяются бесплатно.
' 2. Вы имеете право распространять их на тех же условиях.
' 3. Вы не имеете права использовать имя автора после модификации 
'    исходного кода.
' 4. При этом желательно указывать ссылку на автора оригинальной 
'    версии исходного кода.
' 5. Вы не имеете права на платное распространение исходного кода, 
'    а также программных модулей, содержащих данный исходный код.
' 6. Программа и исходный код распространяются как есть. Автор не 
'    несёт ответственности за любые трагедии или несчастные случаи, 
'    вызванные использованием программы и исходного кода.
' 7. Для любого пункта данного соглашения может быть сделано 
'    исключение с разрешения автора программы.
' 8. По любым вопросам, связанным с данной программой, обращайтесь 
'    по адресу lindaoneesama@gmail.com
' 
' Загружено с http://purl.oclc.org/Linda_Kaioh/Homepage/
'====================================================================
Option Explicit

Dim FSO
Dim TargetFileName
Dim Folder
Dim SourceFileName
Dim Extension

Const AppTitle = "AJPapps - Copy file like folder"

If WScript.Arguments.Count <> 1 Then
  ShowUsage
  WScript.Quit
End If

SourceFileName = WScript.Arguments(0)

Set FSO = CreateObject("Scripting.FileSystemObject")
Set Folder = FSO.GetFolder(".")

Extension = FSO.GetExtensionName(SourceFileName)
If Extension <> "" Then Extension = "." & Extension
TargetFileName = FSO.BuildPath(Folder.Path, Folder.Name & Extension)

If FSO.FileExists(TargetFileName) Then
  If MsgBox(TargetFileName & vbCrLf & vbCrLf & _
            "Файл существует. Заменить?", _
            vbQuestion + vbOkCancel, AppTitle) = vbCancel Then
    WScript.Quit
  End If
End If

On Error Resume Next

FSO.CopyFile SourceFileName, TargetFileName, True
If Err Then
  MsgBox SourceFileName & vbCrlf & vbCrLf & _
         "Не удалось скопировать файл." & vbCrlf & vbCrLf & _
         "Error number: " & Err.Number & vbCrLf & _
         "Description:  " & Err.Description, _
         vbCritical, AppTitle
Else
  MsgBox "Готово! ^_^v", vbInformation, AppTitle
End If

'====================================================================
Sub ShowUsage()
  MsgBox "Использование:" & vbCrLf & vbCrLf & _
         """CopyFileLikeFolder.VBS"" OriginalFileName" & vbCrLf & vbCrLf & _
         "Скопировать файл CopyFileLikeFolder в текущий каталог с " & _
         "именем каталога и расширением оригинального файла. Так, " & _
         "если мы копируем файл C:\Apps\Ariel.EXE в каталог D:\Temp, " & _
         "то конечный файл будет называться D:\Temp\Temp.EXE.", _
         vbInformation, AppTitle
End Sub