'====================================================================
' AJPapps - Hide file
' Линда Кайе 2012. Посвящается Ариэль
' 
' Этот скрипт просто устанавливает атрибут "Скрытый" для файла, 
' переданного через командную строку. Предназначался в первую очередь 
' для работы с Total Commander.
' 
' • 28.01.2012
'   Первая версия ^^
' 
' • 1.07.2012
'   [+] Теперь скрыть можно разом несколько файлов, передав их имена 
'       через командную строку.
' 
'====================================================================
' Маленький копирайт
' 
' 1. Программа и исходный код распространяются бесплатно.
' 2. Вы имеете право распространять их на тех же условиях.
' 3. Вы не имеете права использовать имя автора после модификации 
'    исходного кода.
' 4. При этом желательно указывать ссылку на автора оригинальной 
'    версии исходного кода.
' 5. Вы не имеете права на платное распространение исходного кода, 
'    а также программных модулей, содержащих данный исходный код.
' 6. Программа и исходный код распространяются как есть. Автор не 
'    несёт ответственности за любые трагедии или несчастные случаи, 
'    вызванные использованием программы и исходного кода.
' 7. Для любого пункта данного соглашения может быть сделано 
'    исключение с разрешения автора программы.
' 8. По любым вопросам, связанным с данной программой, обращайтесь 
'    по адресу lindaoneesama@gmail.com
' 
' Загружено с http://purl.oclc.org/Linda_Kaioh/Homepage/
'====================================================================
Option Explicit

Dim FSO
Dim File
Dim TMP
Dim TXT

Const AppTitle = "AJPapps - Hide file"

On Error Resume Next

If WScript.Arguments.Count = 0 Then
  MsgBox "Usage: HideFile.VBS FileNameToHide [FileNameToHide ...]", _
         vbInformation, AppTitle
  WScript.Quit
End If

Set FSO = CreateObject("Scripting.FileSystemObject")

For TMP = 0 To WScript.Arguments.Count - 1
  Err.Clear
  Set File = FSO.GetFile(WScript.Arguments(TMP))
  
  If Err.Number <> 0 Then
    Err.Clear
    Set File = FSO.GetFolder(WScript.Arguments(TMP))
  End If
  
  If Err.Number = 0 Then
    File.Attributes = File.Attributes Or 2 ' vbHidden
  Else
    TXT = TXT & WScript.Arguments(TMP) & vbCrLf & _
                vbTab & Err.Description & vbCrLf
  End If
  
  Set File = Nothing
Next

If TXT <> "" Then
  If Right(TXT, 2) = vbCrLf Then TXT = Left(TXT, Len(TXT) - 2)
  MsgBox "Can't hide these files:" & vbCrLf & vbCrLf & _
         TXT, vbCritical, AppTitle
End If

Set FSO = Nothing