'====================================================================
' AJPapps - MDI2TIFF
' Линда Кайе 2012. Посвящается Ариэль
' 
' Этот скрипт конвертирует MDI файлы в TIF, используя Microsoft 
' Document Imaging из комплекта Office 2003. При этом никакой 
' интерфейс не показывается, всё происходит в фоновом режиме.
' 
' • 23.01.2012
'   Первая версия ^^
' 
'====================================================================
' Маленький копирайт
' 
' 1. Программа и исходный код распространяются бесплатно.
' 2. Вы имеете право распространять их на тех же условиях.
' 3. Вы не имеете права использовать имя автора после модификации 
'    исходного кода.
' 4. При этом желательно указывать ссылку на автора оригинальной 
'    версии исходного кода.
' 5. Вы не имеете права на платное распространение исходного кода, 
'    а также программных модулей, содержащих данный исходный код.
' 6. Программа и исходный код распространяются как есть. Автор не 
'    несёт ответственности за любые трагедии или несчастные случаи, 
'    вызванные использованием программы и исходного кода.
' 7. Для любого пункта данного соглашения может быть сделано 
'    исключение с разрешения автора программы.
' 8. По любым вопросам, связанным с данной программой, обращайтесь 
'    по адресу lindaoneesama@gmail.com
' 
' Загружено с http://purl.oclc.org/Linda_Kaioh/Homepage/
'====================================================================
Option Explicit

Dim Doc
Dim InFileName
Dim OutFileName

Const AppTitle = "AJPapps - MDI2TIFF"

Const miCOMP_LEVEL_LOW = 0
Const miCOMP_LEVEL_MEDIUM = 1
Const miCOMP_LEVEL_HIGH = 2

Const miFILE_FORMAT_DEFAULTVALUE = -1
Const miFILE_FORMAT_TIFF = 1
Const miFILE_FORMAT_TIFF_LOSSLESS = 2
Const miFILE_FORMAT_MDI = 4

If WScript.Arguments.Count = 1 Then
  InFileName = WScript.Arguments(0)
Else
  MsgBox "Usage: MDI2TIF.VBS MDIFileName", vbInformation, AppTitle
  WScript.Quit
End If

If UCase(Right(InFileName, 4)) <> ".MDI" Then
  MsgBox "File must have MDI extension.", vbCritical, AppTitle
  WScript.Quit
End If

OutFileName = Left(InFileName, Len(InFileName) - 3) & "TIF"

On Error Resume Next

Set Doc = CreateObject("MODI.Document")
If Err.Number <> 0 Then
  MsgBox "Can't create MODI object.", vbCritical, AppTitle
  WScript.Quit
End If

Doc.Create InFileName
If Err.Number <> 0 Then
  MsgBox InFileName & vbCrLf & vbCrLf & _
         "Can't open MDI file.", _
         vbCritical, AppTitle
  WScript.Quit
End If

Doc.SaveAs OutFileName, miFILE_FORMAT_TIFF, miCOMP_LEVEL_HIGH
If Err.Number <> 0 Then
  MsgBox OutFileName & vbCrLf & vbCrLf & _
         "Can't save TIFF file.", _
         vbCritical, AppTitle
  WScript.Quit
End If

Doc.Close
Set Doc = Nothing

MsgBox OutFileName & vbCrLf & vbCrLf & _
       "File was saved succesfully.", _
       vbInformation, AppTitle